|  |  |
| --- | --- |
|  | **Министерство науки и высшего образования Российской Федерации**  **Федеральное государственное бюджетное образовательное учреждение**  **высшего образования**  **«Московский государственный технический университет**  **имени Н.Э. Баумана**  **(национальный исследовательский университет)»**  **(МГТУ им. Н.Э. Баумана)** |

ФАКУЛЬТЕТ **Информатика и системы управления**

КАФЕДРА **Компьютерные системы и сети (ИУ6)**

НАПРАВЛЕНИЕ ПОДГОТОВКИ **09.03.01 Информатика и вычислительная техника**

**Отчет**

|  |  |
| --- | --- |
| **по лабораторной работе №** | 3 |

**Название:**

Арифметическая обработка данных.

**Дисциплина:** Микропроцессорные системы.

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
| Студент | ИУ6-62Б |  |  | С.В. Астахов, Д.И. Вариханов |
|  | (Группа) |  | (Подпись, дата) | (И.О. Фамилия) |
|  |  |  |  |  |
| Преподаватель |  |  |  |  |
|  |  |  | (Подпись, дата) | (И.О. Фамилия) |

Москва, 2022

**Вариант 1.**

**Цели работы:**

* изучение способов представления числовых данных в микроконтроллерах;
* изучение двоичных арифметических операций;
* программирование арифметических процедур.

**Ход работы.**

**Задание 1.**

Изучить программу для исследования арифметических операций в стартовом

наборе STK500, приведенную ниже.

Алгоритм программы приведен на рисунках 1 и 2.




Рисунок 1 – схема алгоритма





Рисунок 2 – схема алгоритма

Исходный код:

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;Программа тестирования в STK500 двоичных арифметических операций

; сложения, вычитания, умножения, деления

;Порт PD - порт управления для выбора операндов и операций

;Порт PB - порт индикации исходных операндов и результатов операции

;Соединения шлейфами: порт PB-LED, порт PD-SW

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

.include "m8515def.inc" ;файл определений для ATmega8515

;назначение входов порта PD

.equ SW\_op\_AL = 0 ;кнопка выбора операнда op\_AL

.equ SW\_op\_AH = 1 ;кнопка выбора операнда op\_AH

.equ SW\_op\_BL = 2 ;кнопка выбора операнда op\_ВL

.equ SW\_ADD = 3 ;кнопка операции сложения res=op\_AL+op\_ВL

.equ SW\_SUB = 4 ;кнопка операции вычитания res=op\_AL-op\_ВL

.equ SW\_MUL = 5 ;кнопка операции умножения shov.res=op\_AL x op\_ВL

.equ SW\_DIV = 6 ;кнопка операции деления res=op\_AH.op\_AL/op\_ВL

.equ SW\_SHOW = 7 ;кнопка для просмотра признаков сложения-вычитания,

;старшего байта произведения или остатка при делении

.def op\_AL = r16 ;1-й операнд АL

.def op\_AH = r17 ;старший байт делимого AH

.def op\_BL = r18 ;2-й операнд ВL

.def res = r1 ;результат операции (сумма, разность,

; младший байт произведения или частное)

.def show = r31 ;регистр признаков сложения-вычитания,

; старшего байта произведения или остатка при делении

.def mul\_l = r21 ;младший байт произведения

.def mul\_h = r22 ;старший байт произведения

.def copy\_AH = r23 ;копия старшего байта делимого

.def copy\_AL = r24 ;копия младшего байта делимого

.def copy\_BL = r25 ;копия множителя

.def temp = r26 ;временный регистр

.def sw\_reg = r27 ;регистр состояния кнопок

.def count = r28 ;число операндов в таблице операндов

.def c\_bit = r29 ;счетчик циклов умножения (деления)

.macro vvod ;ввод операнда

lpm ;считывание байта из flash-памяти в r0

mov @0,r0 ; и пересылка в регистр операнда

mov res, r0

adiw zl, 1 ;увеличение указателя адреса на 1

dec count

brne exit

ldi ZL,low(tabl\_op\*2) ;перезагрузка начала таблицы операндов

ldi ZH,high(tabl\_op\*2) ; в регистр Z

ldi count, 10 ;число заданных операндов в таблице 10

exit: nop

.endmacro

.org $000

;Инициализация стека, портов, адреcного регистра Z

ldi temp,low(RAMEND) ;установка

out SPL,temp ; указателя стека

ldi temp,high(RAMEND) ; на последнюю

out SPH,temp ; ячейку ОЗУ

ser temp ;настройка

out DDRB,temp ; порта PB

out PORTB,temp ; на вывод

clr temp ;настройка

out DDRD,temp ; порта PD

ser temp ; на

out PORTD,temp ; ввод

ldi ZL,low(tabl\_op\*2) ;загрузка адреса таблицы операндов

ldi ZH,high(tabl\_op\*2) ; в регистр Z

ldi count,10 ;число операндов 10

;Опрос кнопок и выполнение заданных действий

LOOP: in sw\_reg,PIND

sbrs sw\_reg,0

rjmp f\_op\_AL

sbrs sw\_reg,1

rjmp f\_op\_AH

sbrs sw\_reg,2

rjmp f\_op\_BL

sbrs sw\_reg,3

rjmp add\_bin

sbrs sw\_reg,4

rjmp sub\_bin

sbrs sw\_reg,5

rjmp mul\_bin

sbrs sw\_reg,6

rjmp div\_bin

sbrc sw\_reg,7

rjmp loop

mov res,show

rjmp outled

;Выборка 1-го операнда из таблицы операндов

f\_op\_AL: vvod op\_AL

rjmp outled

;Выборка старшего байта 1-го операнда (при делении)

f\_op\_AH: vvod op\_AH

rjmp outled

;Выборка 2-го операнда

f\_op\_BL: vvod op\_BL

rjmp outled

;Сложение 8-разрядных операндов

add\_bin: mov res,op\_AL

add res,op\_BL

in show,SREG ;выборка из регистра SREG

rjmp outled

;Вычитание 8-разрядных операндов

sub\_bin: mov res,op\_AL

sub res,op\_BL

in show,SREG ;выборка из регистра SREG

rjmp outled

;Умножение 8-разрядных операндов

mul\_bin: mul op\_AL,op\_BL

mov show,r1 ;копируем старший и

mov res,r0 ; младший байт произведения

rjmp outled

;Деление 16-разрядного числа на 8-разрядное

div\_bin: sbrc op\_AH,7 ;ошибки исходных данных

rjmp error

sbrc op\_BL,7

rjmp error

tst op\_BL ;ошибка при делении на 0

breq error

cp op\_AH,op\_BL ;ошибка при переполнении

brge error

clr res ;обнуляем частное

ldi c\_bit,8 ; число итераций

mov copy\_AH,op\_AH

mov copy\_AL,op\_AL

L4: clc

rol copy\_AL ;сдвиг

rol copy\_AH ; делимого

lsl res ;сдвиг частного влево

sub copy\_AH,op\_BL ;вычитание делителя

brcs recov ;если остаток < 0,переход

inc res ; иначе добавить 1 в частное

rjmp L5

recov: add copy\_AH,op\_BL ;восстановление остатка

L5: dec c\_bit

brne L4

mov show,copy\_AH ;пересылка остатка

rjmp outled

error: clr temp ;сигнал об ошибке деления

out PORTB, temp

rcall delay

ser temp

out PORTB, temp

rjmp wait

outled: com res

out portb,res

rcall delay

wait: in sw\_reg,PIND ;ждать, пока кнопка не отпущена

com sw\_reg

brne wait

rjmp loop

; Задержка

DELAY: ldi r19,10

m1: ldi r20,1;250

m3: ldi r21,250

m2: dec r21

brne m2

dec r20

brne m3

dec r19

brne m1

ret

; Таблица операндов в шестнадцатеричном представлении

tabl\_op: .db 0x9C, 0xF0, 0xF6, 0x2A, 0x6F, 0x5F, 0x8A, 0x5F, 0xF6, 0xB1

**Задание 2.**

Выполнить ряд примеров на сложение и вычитание, выбирая операнды слагаемых АL и ВL нажатием кнопок SW0 и SW2. Объяснить результаты операций при нажатиях кнопки SW3 (сложение) и SW4 (вычитание), рассматривая операнды как беззнаковые числа, затем как числа со знаком.

Результаты наблюдений показаны в таблице 1.

Таблица 1 - результаты операций сложения и вычитания

|  |  |  |  |
| --- | --- | --- | --- |
| Число А2/А10 | Число В2/В10 | А+В/А-В | Признаки:  H-S-V-N-Z-C |
| 1001 1100 / 156  Беззнаковое | 1111 0000 / 240  Беззнаковое | 1000 1100 (140)  1010 1100 (172) | 0 - - - 0 1  0 - - - 0 1 |
| 1111 0110 / 246  Беззнаковое | 0010 1010 / 42  Беззнаковое | 0010 0000 (32)  1100 1100 (204) | 1 - - - 0 1  1 - - - 0 0 |
| 1000 1010 / -118  Со знаком | 0101 1111 / 95  Со знаком | 1110 1001 (-23)  0010 1011 (43) | 110100  111000 |
| 1111 0110 / -10  Со знаком | 1011 0001 / -79  Со знаком | 1010 0111 (-89)  0100 0101 (69) | 010101  000000 |

**Задание 3.**

Выполнить ряд примеров умножения 8-разрядных двоичных чисел.

Схема алгоритма умножения показана на рисунке 2.




Рисунок 2 – схема алгоритма умножения

Результаты работы программы показаны в таблице 2.

Таблица 2 - результаты умножения

|  |  |  |
| --- | --- | --- |
| Число А2/А10 | Число В2/В10 | Результат |
| 1111 0000 / 240 | 1111 0110 / 246 | 1110 0110 1010 0000 (59040) |
| 1001 1100 / 156 | 0010 1010 / 42 | 0001 1001 1001 1000 (6552) |
| 0110 1111 / 111 | 1000 1010 / 138 | 0011 1011 1101 0110 (15318) |

**Задание 4.**

Выполнить деление беззнаковых чисел, 16-разрядного делимого на 8-разрядный делитель, с восстановлением остатка при условиях, что делитель 8 не равен 0 и его значение не вызовет переполнения, а также делимое и делитель заданы с нулевыми значениями старших разрядов.

Выполнить 2-3 примера на деление двоичных чисел, самостоятельно подобрав делимое и делитель.

Подобрать пример с максимальными значениями делимого AH.AL и делителя B, при которых частное С будет равно 0b 1111 1111, изменив в случае необходимости программную таблицу операндов.

Схема алгоритма деления представлена на рисунке 3.




Рисунок 3 – схема алгоритма деления

Подберем максимальное делимое и делитель при частном 1111 11112 = 25510. Попробуем в качестве делителя взять максимально допустимое число 0111 11112 = 12710. При фиксированном частном, делимое, очевидно, пропорционален делителю. Делимое AH:AL = 127\*255 + (127-1) = 3251110 = 0111 1110 1111 11112 . Данные представлены в последней строке таблицы 3.

Результаты деления представлены в таблице 3.

Таблица 3 – результаты деления

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
| (AH:AL)2/(AH:AL)10 | BL2/BL10 | Частное | Остаток | Проверка |
| 0111 1111 1000 0000 / 32640 | 1000 0000 / 128 | 1111 1111 / 255 | 0000 0000 / 0 | 32640 = 255\*128 + 0 |
| 0010 1010 0110 1111 / 10863 | 0101 1111 / 95 | 0111 0010 / 114 | 0010 0001 / 33 | 10863 = 114\*95 + 33 |
| 0001 0101 0000 0000 / 5376 | 0110 0100 / 100 | 0011 0101 / 53 | 0100 1100 / 76 | 5376 = 53\*100 + 76 |
| 0111 1110 1111 1111/ 32511 | 0111 1111/ 127 | 1111 1111 / 255 | 0111 1110 / 0  126 | 32511 = 255\*127 + 126 |

Работа алгоритма деления для делимого 537610 и делителя 10010:

537610 = 0001 0101 0000 00002

10010 = 0110 01002

-10010 = 1001 11002 (дополнительный код)

С – частное

0001 0101 0000 0000

+ 1001 1100

1011 0001 - пробное вычитание В, так как разность меньше 0, то

переполнения нет

0010 1010 0000 000x - сдвиг А влево

+ 1001 1100

1100 0110 - вычитание В, остаток меньше 0, значит разряд частного (с7) = 0

0101 0100 0000 00xx

+ 1001 1100

1111 0000 - вычитание В, остаток меньше 0, значит разряд частного (с6) = 0

1010 1000 0000 0xxx

+ 1001 1100

1 0100 0100 - вычитание В, остаток больше 0, значит разряд частного (с5) = 1

1000 1000 0000 xxxx

+ 1001 1100

1 0010 0100 - вычитание В, остаток больше 0, значит разряд частного (с4) = 1

0100 1000 000x xxxx

+ 1001 1100

1110 0100 - вычитание В, остаток меньше 0, значит разряд частного (с3) = 0

1001 0000 00xx xxxx

+ 1001 1100

1 0010 1100 - вычитание В, остаток больше 0, значит разряд частного (с2) = 1

0101 1000 0xxx xxxx

+ 1001 1100

1111 0100 - вычитание В, остаток меньше 0, значит разряд частного (с1) = 0

1011 0000 xxxx xxxx

+ 1001 1100

1 0100 1100 - вычитание В, остаток больше 0, значит разряд частного (с0) = 1

C = 0011 01012 = 5310

Остаток 0100 11002 = 7610

**Вывод:** в ходе данной лабораторной работы были изучены способы представления числовых данных в микроконтроллерах, флаги арифметических операций, а также алгоритмы умножения и деления, ограничения для входных данных алгоритма деления (делитель не равен 0 и его значение не вызовет переполнения, а также делимое и делитель заданы с нулевыми значениями старших разрядов).